Props to you.  I basically understand it.  I learn by taking source code of 
programs apart and trying various things.  So thanks again!  If you want to 
see my finished logo for proposal, I'll be happy to send it to you.  Now its 
off to combining the alphabet blocks (or my own) to this.  Should look 
prerty convincing.
"Bob Hughes" <omn### [at] charternet> wrote in message 
news:4212c756$1@news.povray.org...
> "Daniel" <new### [at] hotmailcom> wrote in message 
> news:42129027$1@news.povray.org...
>> Can some1 please make me a sample?  I'm very new at POV ray.
>
> Since you're new to this I sure hope you can figure out what I've done 
> here:
>
> // BEGIN HERE
> global_settings {
> assumed_gamma 1
> }
>
> camera {location -3*z up y right image_width/image_height*x look_at 0}
>
> light_source {<100,100,-100>,1}
>
> #declare ImagePart=
> texture {
>  pigment {
>   image_map {
>   png "alpha.png"
>  }
> }
> }
>
> #declare InvisiblePart=
> texture {
>  pigment {
>   rgbt 1
>  }
> }
>
> // thick-walled box
> intersection {
> height_field {
>  png "alpha.png"
>  water_level 0.005 // remove lowest/darkest part
>  // some adjustments to get into place
>  rotate -90*x
>  scale <1.001,1.001,2>
>  translate 0.5*z
> }
> difference {
>  box {
>   0,1 // outside
>  }
>  box {
>   0.1,0.9 // inside
>  }
> }
> texture {
>  gradient z
>  texture_map {
>   [0.1 ImagePart] // trying to match thickness surface...
>   [0.1 InvisiblePart] // ... so are transformations below
>  }
>  scale <1.02,1.02,2> // some adjustments to get into place...
>  translate <-0.01,-0.01,-0.01> // ... so that coverage is good
> }
> translate <-0.5,-0.5,-0.5> // center on world origin
> rotate <0,-45,0> // turn to show thickness better
> }
>
> // show where box is
> difference {
>  box {
>   0,1 // outside edges
>  }
>  box {
>   0.01,0.99 // cutaway sides
>    scale <1.1,1,1> translate -0.015*x
>  }
>  box {
>   0.01,0.99 // cutaway top/bottom
>    scale <1,1.1,1> translate -0.015*y
>  }
>  box {
>   0.01,0.99 // cutaway front/back
>    scale <1,1,1.1> translate -0.015*z
>  }
>  pigment {
>   color rgb 1
>  }
> translate <-0.5,-0.5,-0.5> // center on world origin
> rotate <0,-45,0> // turn to show thickness better
> }
> // END HERE
>
> No doubt this complicated to go through just for a simple thing such as 
> this but I'm not able to think of a better way. Obviously there's a whole 
> lot of juggling the positions around to fit it all together right, and I 
> suppose you'll be changing it to do what you want.
>
> Maybe this will help anyhow. You can always ask more questions.
>
> Bob Hughes
>
>

Post a reply to this message